Aula 23 - Definição de Vetores

Introdução#

Até agora vimos como utilizar variáveis para armazenar um único valor, seja um número, uma letra ou um texto e isso foi o suficiente para resolver os problemas que vimos até agora. Porém, em outros casos precisamos lidar com diversos valores e não é viável criar uma variável para cada um deles. Por exemplo:

Pense se você tivesse que criar um programa para calcular a média aritmética de 300 variáveis, neste caso seria bastante trabalhoso criar 300 variáveis para armazenar os valores;
Imagine que você tenha que dizer qual que é o maior e menor número de uma lista de 10.000 números, nessa situação você precisaria criar 10.000 variáveis para armazenar cada um dos números e diversas linhas de código para conseguir comparar qual é o maior e qual é o menor;
Suponha que você tenha que criar um programa que leia 1.000.000.000 números e seu programa deve ordenar esses números em ordem crescente. E por fim mostrar na tela;

Essas são algumas das situações em que a utilização de vetores irá te facilitar.

Definição#

Um vetor, também conhecido como array, é um conjunto de elementos consecutivos do mesmo tipo que podem ser acessados por meio de um índice.

Em termos práticos um vetor é uma variável que armazena diversos valores do mesmo tipo. E como todos esses valores estão armazenados numa única variável você precisará de algo para distinguir quais dos valores você deseja acessar e para isso você terá que fornecer um índice (um número inteiro). Como

Sintaxe#

Agora vamos ver como que declara um vetor no Visualg. Para declarar um vetor você deve utilizar a seguinte sintaxe:

v: vetor[1..5] de inteiro

Mais detalhes#

Agora que já sabemos como declarar um vetor vamos ver alguns detalhes importantes sobre eles.

`v[1]`	`v[2]`	`v[3]`	`v[4]`	`v[5]`
10	1	23	500	80

Essa tabela representa um vetor de 5 posições que armazena valores do tipo inteiro. Quando fazemos v[1] estamos acessando o primeiro valor do vetor v, quando fazemos v[2] estamos acessando o segundo valor do vetor e assim por diante.

Como cada valor possui um espaço próprio, nós podemos alterar o valor de v[1] (número 10) sem alterar o valor de v[2] (número 1) e assim por diante.

Exemplo#

Exemplo 1#

Para começar vamos pegar um exemplo simples. Vamos criar um programa que irá receber as três notas de um aluno e calcular a média aritmética das notas.

$ Digite a nota 1: 10
$ Digite a nota 2: 2
$ Digite a nota 3: 3

A nota 1 foi: 10
A nota 2 foi: 2
A nota 3 foi: 3

A média final é: 5.0

Solução#

exemplo1.alg

algoritmo "vetores"
var

v: vetor [1..3] de real
indice: inteiro
media: real

inicio
    para indice de 1 ate 3 faca
        escreva("Digite a nota ", indice, ": ")
        leia(v[indice])
    fimpara

    para indice de 1 ate 3 faca
        escreval("A nota ", indice, " foi: ", v[indice])
        media <- media + v[indice]
    fimpara

    escreval("A média final é: ", media/3)
fimalgoritmo

Exemplo 2#

Seguindo o exemplo anterior, agora vamos criar um programa que calcule a média de 100 notas.

exemplo2.alg

algoritmo "vetores"
var

v: vetor [1..100] de real
indice: inteiro
media: real

inicio
    para indice de 1 ate 100 faca
        escreva("Digite a nota ", indice, ": ")
        leia(v[indice])
    fimpara

    para indice de 1 ate 100 faca
        escreval("A nota ", indice, " foi: ", v[indice])
        media <- media + v[indice]
    fimpara

    escreval("A média final é: ", media/100)
fimalgoritmo

Veja como foi simples criar um programa que calcula a média de 100 notas. Só precisamos alterar 4 linhas para que nosso programa funcione com 100 notas ao invés de 3.

Aula em vídeo#

Caso prefira também existe o conteúdo em forma de vídeo

Referências#

Documentação da linguagem Portugol

Desafios#

Caso queira treinar um pouco mais você pode ver o(s) seguinte(s) enunciado(s):