Aula 25 - Exercício salário
Continuando a nossa série de aulas sobre vetores, vamos realizar um exercício para consolidar o conhecimento.
Questão#
Um trabalhador autônomo deseja saber quanto recebe ao mês e ao ano. Para facilitar isso ele te contratou para criar um programa em que ele irá digitar o valor de serviço e o número que corresponde ao mês em que ele recebeu. Então seu programa deve mostrar quanto ele recebeu em cada mês e no ano.
Além disso, o programa deverá conter um menu onde o usuário irá informar se deseja cadastrar um novo serviço, exibir o relatório ou sair.
[1] Informar um novo serviço
[2] Exibir relatório
[3] Sair
Digite o número de uma das opções:
$ 1
Digite o valor recebido do serviço:
$ 1000
Digite o mês em que foi recebido:
$ 2
[1] Informar um novo serviço
[2] Exibir relatório
[3] Sair
$ 2
---- MESES ----
Mês: 1 R$: 0
Mês: 2 R$: 1000
Mês: 3 R$: 0
Mês: 4 R$: 0
Mês: 5 R$: 0
Mês: 6 R$: 0
Mês: 7 R$: 0
Mês: 8 R$: 0
Mês: 9 R$: 0
Mês: 10 R$: 0
Mês: 11 R$: 0
Mês: 12 R$: 0
---- ANO ----
Recebido no ano: R$ 1000
Solução#
exercicio.alg
algoritmo "Exercicio"
var
valMes: vetor [0..11] de real
valAno: real
valSer: real
mes:inteiro
opt: caractere
tecla: caractere
inicio
repita
limpatela
escreval("[1] Informar um novo serviço")
escreval("[2] Exibir relatório")
escreval("[3] Sair")
escreva("Digite o número de uma das opções:")
leia(opt)
se opt = "3" entao
interrompa
fimse
se opt = "1" entao
escreva("Digite o valor recebido do serviço:")
leia(valSer)
escreva("Digite o mês em que foi recebido:")
leia(mes)
valMes[mes - 1] <- valSer + valMes[mes - 1]
valAno <- valSer + valAno
fimse
se opt = "2" entao
escreval("----MESES----")
para mes de 0 ate 11 faca
escreval("Mês:", mes + 1, " R$:", valMes[mes])
fimpara
escreval("----ANO----")
escreval("Recebido no ano: R$", valAno)
leia(tecla)
fimse
fimrepita
fimalgoritmo
Aula em vídeo#
Caso prefira também existe o conteúdo em forma de vídeo
Desafios#
Caso queira treinar um pouco mais você pode ver o(s) seguinte(s) enunciado(s):